<!--WSS

DEF VAR RCSVersion AS CHARACTER INIT "$Header: /home/appl/srvexp/srcadm/adm21/RCS/ParameterMaintenance.html,v 1.4 2003/05/07 18:06:31 sauge Exp sauge $" NO-UNDO. 

DEF VAR cCurApplication    AS CHARACTER NO-UNDO.
DEF VAR cCurGroup          AS CHARACTER NO-UNDO.
DEF VAR cListApplication   AS CHARACTER NO-UNDO.
DEF VAR cListGroup         AS CHARACTER NO-UNDO.
DEF VAR cRowID             AS CHARACTER NO-UNDO.

{htmltools.i}

/*************************************************************************/
/* Function that will list all the possible applications                 */
/*************************************************************************/

FUNCTION ListApplications RETURNS CHARACTER:

  DEF VAR cList AS CHARACTER NO-UNDO.

  FOR EACH Parms NO-LOCK:

     IF can-do(cList, Parms.Application) = NO THEN
       ASSIGN cList = cList + Parms.Application + ",".

  END. /* FOR EACH Parms */

  RETURN SUBSTRING(cList, 1, LENGTH(cList) - 1).

END. /* FUNCTION ListApplications */

/*************************************************************************/
/* Function that will list all the possible groups within an application */
/*************************************************************************/

FUNCTION ListGroups RETURNS CHARACTER (INPUT cApplication AS CHARACTER):

  DEF VAR cList AS CHARACTER NO-UNDO.

  FOR EACH Parms NO-LOCK
  WHERE Parms.Application = cApplication:

     IF Can-DO(cList, Parms.GroupName) = NO THEN
       ASSIGN cList = cList + Parms.GroupName + ",".

  END. /* FOR EACH Parms */

  RETURN SUBSTRING(cList, 1, LENGTH(cList) - 1).

END.

/*************************************************************************/
/* Determine the current application we are working on.                  */
/*************************************************************************/

ASSIGN cCurApplication = GET-VALUE("Application").
ASSIGN cCurGroup = GET-VALUE("Group").

/*************************************************************************/
/* Determine if we are deleting a parameter.                             */
/*************************************************************************/

IF GET-VALUE("Action") = "Delete" THEN DO:

  ASSIGN cRowID = GET-VALUE("RowID").

  FIND Parms EXCLUSIVE-LOCK 
  WHERE ROWID(Parms) = TO-ROWID(cRowID)
  NO-ERROR.

  IF AVAILABLE Parms THEN DELETE Parms.

END.

/*************************************************************************/
/* Prep our listings of applications and groups based on application     */
/* chosen.                                                               */
/*************************************************************************/

ASSIGN cListApplication = ListApplications().
IF cCurApplication <> "" THEN cListGroup = ListGroups(cCurApplication).

/*************************************************************************/
/* Determine if we are posting from the submit button.  This is known    */
/* from the switch value DisplayedParameters.  If YES, then we have dis- */
/* played the parameters and can assume the user got here via the submit */
/* button.                                                               */
/*************************************************************************/

IF GET-VALUE("DisplayedParameters") = "YES" THEN DO:

  /*************************************************************************/
  /* Make sure we got here via the submit button and not via a change of   */
  /* application or group name.  If we are on the same group and ap-       */
  /* application, make the changes to the record.                          */
  /*************************************************************************/

  IF GET-VALUE("PreviousApplication") = cCurApplication
  AND GET-VALUE("PreviousGroup") = cCurGroup THEN DO: 

    FOR EACH Parms EXCLUSIVE-LOCK
    WHERE Parms.Application = cCurApplication
      AND Parms.GroupName = cCurGroup:

      ASSIGN Parms.ParmValue = GET-VALUE("Value." + STRING(RowID(Parms))).

    END. /* FOR EACH Parms */

  END. /* IF GET-VALUE("PreviousApplication") = cCurApplication... */

END. /* IF GET-VALUE("DisplayedParameters") = "YES" */

-->
<html>
<head>
<title>Parameters Maintenance</title>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
</head>

<body bgcolor="#FFFFFF">
<p align="center"><b>Parameters Maintenance</b></p>
<form method="post" name="a">
  <table width="90%" border="0" align="center" cellspacing="0">
    <tr bgcolor="#CCCCCC"> 
      <td> 
        <div align="center"><b>Application</b></div>
      </td>
      <td> 
        <div align="center"><b>Parameter Group</b></div>
      </td>
    </tr>
    <tr bgcolor="#CCCCCC"> 
      <td> 
        <div align="center"> 
           `HTMLSelect("a","Application",10,cListApplication,cListApplication,cCurApplication,'onChange="this.form.submit()"')`
        </div>
      </td>
      <td> 
        <div align="center"> 
           `HTMLSelect("a","Group",10,cListGroup,cListGroup,cCurGroup,'onChange="this.form.submit()"')`
        </div>
      </td>
    </tr>
  </table>
  <p align="center"><a href="NewParameter.html?Application=`cCurApplication`&GroupName=`cCurGroup`" target="_blank">New Parameter</a></p>
  <p align="center"><a href="ParameterDump.html">Dump Parameters</a></p>
  <table width="90%" border="0" align="center" cellspacing="0">
    <tr bgcolor="#CCCCCC"> 
      <td>
        <div align="center"><b>Delete</b></div>
      </td>
      <td> 
        <div align="center"><b>Parameter Name</b></div>
      </td>
      <td> 
        <div align="center"><b>Parameter Value</b></div>
      </td>
    </tr>
    <!--WSS
    IF cCurGroup <> "" THEN DO:
      -->
      <input type="hidden" name="DisplayedParameters" value="YES">
      <input type="hidden" name="PreviousApplication" value="`cCurApplication`">
      <input type="hidden" name="PreviousGroup" value="`cCurGroup`">
      <!--WSS
      FOR EACH Parms NO-LOCK
      WHERE Parms.Application = cCurApplication
        AND Parms.GroupName = cCurGroup:

        -->
        <tr> 
          <td valign="top">
            <div align="center">
 <a href="ParameterMaintenance.html?Action=Delete&RowID=`STRING(RowID(Parms))`&Application=`cCurApplication`&Group=`cCurGroup`">Delete</a>
            </div>
          </td>
          <td valign="top"> 
            <div align="center"> 
              `Parms.ParmName`
            </div>
          </td>
          <td> 
            <div align="center"> 
<textarea name="Value.`STRING(RowID(Parms))`" cols="40" rows="5">
`HTML-ENCODE(Parms.ParmValue)`
</textarea>
            </div>
          </td>
        </tr>
        <!--WSS
      END. /* FOR EACH Parms */
    END. /* IF cCurGroup <> "" */
  -->
  </table>
  <p align="center">
    <input type="submit" name="Submit" value="Submit">
  </p>
</form>
<p>&nbsp;</p>
</body>
</html>